#acupoftea - mail.ontime-ae.com

System	:	Linux server1.ontime-gulf.com 4.18.0-553.5.1.el8_10.x86_64 #1 SMP Wed Jun 5 09:12:13 EDT 2024 x86_64
Software	:	Apache
Server	:	162.0.230.206
Domains	:	40 Domain
Permission	:	[ drwxr-xr-x ]
	:	/ usr / share / tk8.6 / ttk /

216.73.216.49

Home

File scrollbar.tcl

#
# Bindings for TScrollbar widget
#

# Still don't have a working ttk::scrollbar under OSX -
# Swap in a [tk::scrollbar] on that platform,
# unless user specifies -class or -style.
#
if {[tk windowingsystem] eq "aqua"} {
    rename ::ttk::scrollbar ::ttk::_scrollbar
    proc ttk::scrollbar {w args} {
	set constructor ::tk::scrollbar
	foreach {option _} $args {
	    if {$option eq "-class" || $option eq "-style"} {
		set constructor ::ttk::_scrollbar
		break
	    }
	}
	return [$constructor $w {*}$args]
    }
}

namespace eval ttk::scrollbar {
    variable State
    # State(xPress)	--
    # State(yPress)	-- initial position of mouse at start of drag.
    # State(first)	-- value of -first at start of drag.
}

bind TScrollbar <ButtonPress-1> 	{ ttk::scrollbar::Press %W %x %y }
bind TScrollbar <B1-Motion>		{ ttk::scrollbar::Drag %W %x %y }
bind TScrollbar <ButtonRelease-1>	{ ttk::scrollbar::Release %W %x %y }

bind TScrollbar <ButtonPress-2> 	{ ttk::scrollbar::Jump %W %x %y }
bind TScrollbar <B2-Motion>		{ ttk::scrollbar::Drag %W %x %y }
bind TScrollbar <ButtonRelease-2>	{ ttk::scrollbar::Release %W %x %y }

proc ttk::scrollbar::Scroll {w n units} {
    set cmd [$w cget -command]
    if {$cmd ne ""} {
	uplevel #0 $cmd scroll $n $units
    }
}

proc ttk::scrollbar::Moveto {w fraction} {
    set cmd [$w cget -command]
    if {$cmd ne ""} {
	uplevel #0 $cmd moveto $fraction
    }
}

proc ttk::scrollbar::Press {w x y} {
    variable State

set State(xPress) $x
    set State(yPress) $y

switch -glob -- [$w identify $x $y] {
    	*uparrow -
	*leftarrow {
	    ttk::Repeatedly Scroll $w -1 units
	}
	*downarrow -
	*rightarrow {
	    ttk::Repeatedly Scroll $w  1 units
	}
	*thumb {
	    set State(first) [lindex [$w get] 0]
	}
	*trough {
	    set f [$w fraction $x $y]
	    if {$f < [lindex [$w get] 0]} {
		# Clicked in upper/left trough
		ttk::Repeatedly Scroll $w -1 pages
	    } elseif {$f > [lindex [$w get] 1]} {
		# Clicked in lower/right trough
		ttk::Repeatedly Scroll $w 1 pages
	    } else {
		# Clicked on thumb (???)
		set State(first) [lindex [$w get] 0]
	    }
	}
    }
}

proc ttk::scrollbar::Drag {w x y} {
    variable State
    if {![info exists State(first)]} {
    	# Initial buttonpress was not on the thumb, 
	# or something screwy has happened.  In either case, ignore:
	return;
    }
    set xDelta [expr {$x - $State(xPress)}]
    set yDelta [expr {$y - $State(yPress)}]
    Moveto $w [expr {$State(first) + [$w delta $xDelta $yDelta]}]
}

proc ttk::scrollbar::Release {w x y} {
    variable State
    unset -nocomplain State(xPress) State(yPress) State(first)
    ttk::CancelRepeat
}

# scrollbar::Jump -- ButtonPress-2 binding for scrollbars.
# 	Behaves exactly like scrollbar::Press, except that
#	clicking in the trough jumps to the the selected position.
#
proc ttk::scrollbar::Jump {w x y} {
    variable State

switch -glob -- [$w identify $x $y] {
	*thumb -
	*trough {
	    set State(first) [$w fraction $x $y]
	    Moveto $w $State(first)
	    set State(xPress) $x
	    set State(yPress) $y
	}
	default {
	    Press $w $x $y
	}
    }
}

Name	Type	Size	Permission	Last Modified	Actions
.	DIR	-	drwxr-xr-x	2024-03-13 04:40:23
..	DIR	-	drwxr-xr-x	2024-03-13 04:40:23
altTheme.tcl	text/plain	3.46 KB	-rw-r--r--	2019-10-16 05:25:10
aquaTheme.tcl	text/plain	1.95 KB	-rw-r--r--	2019-10-16 05:25:10
button.tcl	text/plain	2.91 KB	-rw-r--r--	2019-10-16 05:25:10
clamTheme.tcl	text/plain	4.49 KB	-rw-r--r--	2019-10-16 05:25:10
classicTheme.tcl	text/plain	3.6 KB	-rw-r--r--	2019-10-16 05:25:10
combobox.tcl	text/plain	12.13 KB	-rw-r--r--	2019-10-16 05:25:10
cursors.tcl	text/plain	3.91 KB	-rw-r--r--	2019-10-16 05:25:10
defaults.tcl	text/plain	4.25 KB	-rw-r--r--	2019-10-16 05:25:10
entry.tcl	text/plain	16.01 KB	-rw-r--r--	2019-10-16 05:25:10
fonts.tcl	text/plain	5.45 KB	-rw-r--r--	2019-10-16 05:25:10
menubutton.tcl	text/plain	4.8 KB	-rw-r--r--	2019-10-16 05:25:10
notebook.tcl	text/plain	5.49 KB	-rw-r--r--	2019-10-16 05:25:10
panedwindow.tcl	text/plain	1.88 KB	-rw-r--r--	2019-10-16 05:25:10
progress.tcl	text/plain	1.06 KB	-rw-r--r--	2019-10-16 05:25:10
scale.tcl	text/plain	2.63 KB	-rw-r--r--	2019-10-16 05:25:10
scrollbar.tcl	text/plain	3.02 KB	-rw-r--r--	2019-10-16 05:25:10
sizegrip.tcl	text/plain	2.34 KB	-rw-r--r--	2019-10-16 05:25:10
spinbox.tcl	text/plain	4.16 KB	-rw-r--r--	2019-10-16 05:25:10
treeview.tcl	text/plain	8.65 KB	-rw-r--r--	2019-10-16 05:25:10
ttk.tcl	text/plain	4.44 KB	-rw-r--r--	2019-10-16 05:25:10
utils.tcl	text/plain	8.36 KB	-rw-r--r--	2019-10-16 05:25:10
vistaTheme.tcl	text/plain	9.12 KB	-rw-r--r--	2019-10-16 05:25:10
winTheme.tcl	text/plain	2.58 KB	-rw-r--r--	2019-10-16 05:25:10
xpTheme.tcl	text/plain	1.88 KB	-rw-r--r--	2019-10-16 05:25:10

~ ACUPOFTEA - mail.ontime-ae.com