#acupoftea - mail.ontime-ae.com

System	:	Linux server1.ontime-gulf.com 4.18.0-553.5.1.el8_10.x86_64 #1 SMP Wed Jun 5 09:12:13 EDT 2024 x86_64
Software	:	Apache
Server	:	162.0.230.206
Domains	:	40 Domain
Permission	:	[ drwxr-xr-x ]
	:	/ usr / share / perl5 / URI /

216.73.216.49

Home

File WithBase.pm

package URI::WithBase;

use strict;
use warnings;

use URI;
use Scalar::Util 'blessed';

our $VERSION = "2.20";

use overload '""' => "as_string", fallback => 1;

sub as_string;  # help overload find it

sub new
{
    my($class, $uri, $base) = @_;
    my $ibase = $base;
    if ($base && blessed($base) && $base->isa(__PACKAGE__)) {
	$base = $base->abs;
	$ibase = $base->[0];
    }
    bless [URI->new($uri, $ibase), $base], $class;
}

sub new_abs
{
    my $class = shift;
    my $self = $class->new(@_);
    $self->abs;
}

sub _init
{
    my $class = shift;
    my($str, $scheme) = @_;
    bless [URI->new($str, $scheme), undef], $class;
}

sub eq
{
    my($self, $other) = @_;
    $other = $other->[0] if blessed($other) and $other->isa(__PACKAGE__);
    $self->[0]->eq($other);
}

our $AUTOLOAD;
sub AUTOLOAD
{
    my $self = shift;
    my $method = substr($AUTOLOAD, rindex($AUTOLOAD, '::')+2);
    return if $method eq "DESTROY";
    $self->[0]->$method(@_);
}

sub can {                                  # override UNIVERSAL::can
    my $self = shift;
    $self->SUPER::can(@_) || (
      ref($self)
      ? $self->[0]->can(@_)
      : undef
    )
}

sub base {
    my $self = shift;
    my $base  = $self->[1];

if (@_) { # set
	my $new_base = shift;
	# ensure absoluteness
	$new_base = $new_base->abs if ref($new_base) && $new_base->isa(__PACKAGE__);
	$self->[1] = $new_base;
    }
    return unless defined wantarray;

# The base attribute supports 'lazy' conversion from URL strings
    # to URL objects. Strings may be stored but when a string is
    # fetched it will automatically be converted to a URL object.
    # The main benefit is to make it much cheaper to say:
    #   URI::WithBase->new($random_url_string, 'http:')
    if (defined($base) && !ref($base)) {
	$base = ref($self)->new($base);
	$self->[1] = $base unless @_;
    }
    $base;
}

sub clone
{
    my $self = shift;
    my $base = $self->[1];
    $base = $base->clone if ref($base);
    bless [$self->[0]->clone, $base], ref($self);
}

sub abs
{
    my $self = shift;
    my $base = shift || $self->base || return $self->clone;
    $base = $base->as_string if ref($base);
    bless [$self->[0]->abs($base, @_), $base], ref($self);
}

sub rel
{
    my $self = shift;
    my $base = shift || $self->base || return $self->clone;
    $base = $base->as_string if ref($base);
    bless [$self->[0]->rel($base, @_), $base], ref($self);
}

__END__

=head1 NAME

URI::WithBase - URIs which remember their base

=head1 SYNOPSIS

$u1 = URI::WithBase->new($str, $base);
 $u2 = $u1->abs;

$base = $u1->base;
 $u1->base( $new_base )

=head1 DESCRIPTION

This module provides the C<URI::WithBase> class.  Objects of this class
are like C<URI> objects, but can keep their base too.  The base
represents the context where this URI was found and can be used to
absolutize or relativize the URI.  All the methods described in L<URI>
are supported for C<URI::WithBase> objects.

The methods provided in addition to or modified from those of C<URI> are:

=over 4

=item $uri = URI::WithBase->new($str, [$base])

The constructor takes an optional base URI as the second argument.
If provided, this argument initializes the base attribute.

=item $uri->base( [$new_base] )

Can be used to get or set the value of the base attribute.
The return value, which is the old value, is a URI object or C<undef>.

=item $uri->abs( [$base_uri] )

The $base_uri argument is now made optional as the object carries its
base with it.  A new object is returned even if $uri is already
absolute (while plain URI objects simply return themselves in
that case).

=item $uri->rel( [$base_uri] )

The $base_uri argument is now made optional as the object carries its
base with it.  A new object is always returned.

=back

=head1 SEE ALSO

L<URI>

=head1 COPYRIGHT

=cut

Name	Type	Size	Permission	Last Modified	Actions
.	DIR	-	drwxr-xr-x	2024-03-13 04:36:40
..	DIR	-	drwxr-xr-x	2025-07-29 10:57:25
file	DIR	-	drwxr-xr-x	2024-03-13 04:36:40
urn	DIR	-	drwxr-xr-x	2024-03-13 04:36:40
Escape.pm	text/plain	6.9 KB	-rw-r--r--	2018-01-09 06:42:55
Heuristic.pm	text/plain	6.37 KB	-rw-r--r--	2018-01-09 06:42:55
IRI.pm	text/plain	820 B	-rw-r--r--	2018-01-09 06:42:55
QueryParam.pm	text/plain	4.77 KB	-rw-r--r--	2018-01-09 06:42:55
Split.pm	text/plain	2.32 KB	-rw-r--r--	2018-01-09 06:42:55
URL.pm	text/plain	5.36 KB	-rw-r--r--	2018-01-09 06:42:55
WithBase.pm	text/plain	3.77 KB	-rw-r--r--	2018-01-09 06:42:55
_foreign.pm	text/plain	133 B	-rw-r--r--	2018-01-09 06:42:55
_generic.pm	text/plain	5.71 KB	-rw-r--r--	2018-01-09 06:42:55
_idna.pm	text/plain	2.06 KB	-rw-r--r--	2018-01-09 06:42:55
_ldap.pm	text/plain	3.2 KB	-rw-r--r--	2018-01-09 06:42:55
_login.pm	text/plain	257 B	-rw-r--r--	2018-01-09 06:42:55
_punycode.pm	text/plain	5.52 KB	-rw-r--r--	2018-01-09 06:42:55
_query.pm	text/plain	2.5 KB	-rw-r--r--	2018-01-09 06:42:55
_segment.pm	text/plain	442 B	-rw-r--r--	2018-01-09 06:42:55
_server.pm	text/plain	3.66 KB	-rw-r--r--	2018-01-09 06:42:55
_userpass.pm	text/plain	1.04 KB	-rw-r--r--	2018-01-09 06:42:55
data.pm	text/plain	3.34 KB	-rw-r--r--	2018-01-09 06:42:55
file.pm	text/plain	9.53 KB	-rw-r--r--	2018-01-09 06:42:55
ftp.pm	text/plain	1.06 KB	-rw-r--r--	2018-01-09 06:42:55
gopher.pm	text/plain	2.4 KB	-rw-r--r--	2018-01-09 06:42:55
http.pm	text/plain	451 B	-rw-r--r--	2018-01-09 06:42:55
https.pm	text/plain	170 B	-rw-r--r--	2018-01-09 06:42:55
ldap.pm	text/plain	2.88 KB	-rw-r--r--	2018-01-09 06:42:55
ldapi.pm	text/plain	467 B	-rw-r--r--	2018-01-09 06:42:55
ldaps.pm	text/plain	170 B	-rw-r--r--	2018-01-09 06:42:55
mailto.pm	text/plain	1.27 KB	-rw-r--r--	2018-01-09 06:42:55
mms.pm	text/plain	151 B	-rw-r--r--	2018-01-09 06:42:55
news.pm	text/plain	1.45 KB	-rw-r--r--	2018-01-09 06:42:55
nntp.pm	text/plain	153 B	-rw-r--r--	2018-01-09 06:42:55
pop.pm	text/plain	1.2 KB	-rw-r--r--	2018-01-09 06:42:55
rlogin.pm	text/plain	155 B	-rw-r--r--	2018-01-09 06:42:55
rsync.pm	text/plain	233 B	-rw-r--r--	2018-01-09 06:42:55
rtsp.pm	text/plain	151 B	-rw-r--r--	2018-01-09 06:42:55
rtspu.pm	text/plain	152 B	-rw-r--r--	2018-01-09 06:42:55
sftp.pm	text/plain	124 B	-rw-r--r--	2018-01-09 06:42:55
sip.pm	text/plain	1.69 KB	-rw-r--r--	2018-01-09 06:42:55
sips.pm	text/plain	169 B	-rw-r--r--	2018-01-09 06:42:55
snews.pm	text/plain	198 B	-rw-r--r--	2018-01-09 06:42:55
ssh.pm	text/plain	201 B	-rw-r--r--	2018-01-09 06:42:55
telnet.pm	text/plain	154 B	-rw-r--r--	2018-01-09 06:42:55
tn3270.pm	text/plain	154 B	-rw-r--r--	2018-01-09 06:42:55
urn.pm	text/plain	2.15 KB	-rw-r--r--	2018-01-09 06:42:55

~ ACUPOFTEA - mail.ontime-ae.com