#acupoftea - mail.ontime-ae.com

System	:	Linux server1.ontime-gulf.com 4.18.0-553.5.1.el8_10.x86_64 #1 SMP Wed Jun 5 09:12:13 EDT 2024 x86_64
Software	:	Apache
Server	:	162.0.230.206
Domains	:	40 Domain
Permission	:	[ drwxr-xr-x ]
	:	/ usr / share / awk /

216.73.216.6

Home

File getopt.awk

# getopt.awk --- Do C library getopt(3) function in awk
#
# Arnold Robbins, arnold@skeeve.com, Public Domain
#
# Initial version: March, 1991
# Revised: May, 1993

# External variables:
#    Optind -- index in ARGV of first nonoption argument
#    Optarg -- string value of argument to current option
#    Opterr -- if nonzero, print our own diagnostic
#    Optopt -- current option letter

# Returns:
#    -1     at end of options
#    "?"    for unrecognized option
#    <c>    a character representing the current option

# Private Data:
#    _opti  -- index in multiflag option, e.g., -abc
function getopt(argc, argv, options,    thisopt, i)
{
    if (length(options) == 0)    # no options given
        return -1

if (argv[Optind] == "--") {  # all done
        Optind++
        _opti = 0
        return -1
    } else if (argv[Optind] !~ /^-[^:[:space:]]/) {
        _opti = 0
        return -1
    }
    if (_opti == 0)
        _opti = 2
    thisopt = substr(argv[Optind], _opti, 1)
    Optopt = thisopt
    i = index(options, thisopt)
    if (i == 0) {
        if (Opterr)
            printf("%c -- invalid option\n", thisopt) > "/dev/stderr"
        if (_opti >= length(argv[Optind])) {
            Optind++
            _opti = 0
        } else
            _opti++
        return "?"
    }
    if (substr(options, i + 1, 1) == ":") {
        # get option argument
        if (length(substr(argv[Optind], _opti + 1)) > 0)
            Optarg = substr(argv[Optind], _opti + 1)
        else
            Optarg = argv[++Optind]
        _opti = 0
    } else
        Optarg = ""
    if (_opti == 0 || _opti >= length(argv[Optind])) {
        Optind++
        _opti = 0
    } else
        _opti++
    return thisopt
}
BEGIN {
    Opterr = 1    # default is to diagnose
    Optind = 1    # skip ARGV[0]

# test program
    if (_getopt_test) {
        while ((_go_c = getopt(ARGC, ARGV, "ab:cd")) != -1)
            printf("c = <%c>, Optarg = <%s>\n",
                                       _go_c, Optarg)
        printf("non-option arguments:\n")
        for (; Optind < ARGC; Optind++)
            printf("\tARGV[%d] = <%s>\n",
                                    Optind, ARGV[Optind])
    }
}

Name	Type	Size	Permission	Last Modified	Actions
.	DIR	-	drwxr-xr-x	2024-03-13 04:20:09
..	DIR	-	drwxr-xr-x	2025-10-16 10:59:21
assert.awk	text/plain	383 B	-rw-r--r--	2018-02-25 05:17:35
bits2str.awk	text/plain	334 B	-rw-r--r--	2018-02-25 05:17:35
cliff_rand.awk	text/plain	307 B	-rw-r--r--	2018-02-25 05:17:35
ctime.awk	text/plain	234 B	-rw-r--r--	2018-02-25 05:17:35
ftrans.awk	text/plain	315 B	-rw-r--r--	2018-02-25 05:17:35
getopt.awk	text/plain	2.15 KB	-rw-r--r--	2018-02-25 05:17:35
gettime.awk	text/plain	2.43 KB	-rw-r--r--	2018-02-25 05:17:35
group.awk	text/plain	1.72 KB	-rw-r--r--	2022-04-18 03:55:53
have_mpfr.awk	text/plain	221 B	-rw-r--r--	2018-02-25 05:17:35
inplace.awk	text/plain	1.95 KB	-rw-r--r--	2018-02-25 05:17:35
intdiv0.awk	text/plain	462 B	-rw-r--r--	2018-02-25 05:17:35
join.awk	text/plain	378 B	-rw-r--r--	2018-02-25 05:17:35
libintl.awk	text/x-c	238 B	-rw-r--r--	2018-02-25 05:17:35
noassign.awk	text/plain	422 B	-rw-r--r--	2018-02-25 05:17:35
ord.awk	text/plain	937 B	-rw-r--r--	2018-02-25 05:17:35
passwd.awk	text/plain	1.17 KB	-rw-r--r--	2022-04-18 03:55:53
processarray.awk	text/plain	355 B	-rw-r--r--	2018-02-25 05:17:35
quicksort.awk	text/plain	1.01 KB	-rw-r--r--	2018-02-25 05:17:35
readable.awk	text/plain	489 B	-rw-r--r--	2018-02-25 05:17:35
readfile.awk	text/plain	267 B	-rw-r--r--	2018-02-25 05:17:35
rewind.awk	text/plain	404 B	-rw-r--r--	2018-02-25 05:17:35
round.awk	text/plain	661 B	-rw-r--r--	2018-02-25 05:17:35
shellquote.awk	text/plain	472 B	-rw-r--r--	2018-02-25 05:17:35
strtonum.awk	text/plain	1.42 KB	-rw-r--r--	2018-02-25 05:17:35
walkarray.awk	text/plain	214 B	-rw-r--r--	2018-02-25 05:17:35
zerofile.awk	text/plain	424 B	-rw-r--r--	2018-02-25 05:17:35

~ ACUPOFTEA - mail.ontime-ae.com