#acupoftea - mail.ontime-ae.com

System	:	Linux server1.ontime-gulf.com 4.18.0-553.5.1.el8_10.x86_64 #1 SMP Wed Jun 5 09:12:13 EDT 2024 x86_64
Software	:	Apache
Server	:	162.0.230.206
Domains	:	40 Domain
Permission	:	[ drwxr-xr-x ]
	:	/ usr / share / aclocal /

216.73.216.49

Home

File longlong.m4

# longlong.m4 serial 17
dnl Copyright (C) 1999-2007, 2009-2016 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

dnl From Paul Eggert.

# Define HAVE_LONG_LONG_INT if 'long long int' works.
# This fixes a bug in Autoconf 2.61, and can be faster
# than what's in Autoconf 2.62 through 2.68.

# Note: If the type 'long long int' exists but is only 32 bits large
# (as on some very old compilers), HAVE_LONG_LONG_INT will not be
# defined. In this case you can treat 'long long int' like 'long int'.

AC_DEFUN([AC_TYPE_LONG_LONG_INT],
[
  AC_REQUIRE([AC_TYPE_UNSIGNED_LONG_LONG_INT])
  AC_CACHE_CHECK([for long long int], [ac_cv_type_long_long_int],
     [ac_cv_type_long_long_int=yes
      if test "x${ac_cv_prog_cc_c99-no}" = xno; then
        ac_cv_type_long_long_int=$ac_cv_type_unsigned_long_long_int
        if test $ac_cv_type_long_long_int = yes; then
          dnl Catch a bug in Tandem NonStop Kernel (OSS) cc -O circa 2004.
          dnl If cross compiling, assume the bug is not important, since
          dnl nobody cross compiles for this platform as far as we know.
          AC_RUN_IFELSE(
            [AC_LANG_PROGRAM(
               [[@%:@include <limits.h>
                 @%:@ifndef LLONG_MAX
                 @%:@ define HALF \
                          (1LL << (sizeof (long long int) * CHAR_BIT - 2))
                 @%:@ define LLONG_MAX (HALF - 1 + HALF)
                 @%:@endif]],
               [[long long int n = 1;
                 int i;
                 for (i = 0; ; i++)
                   {
                     long long int m = n << i;
                     if (m >> i != n)
                       return 1;
                     if (LLONG_MAX / 2 < m)
                       break;
                   }
                 return 0;]])],
            [],
            [ac_cv_type_long_long_int=no],
            [:])
        fi
      fi])
  if test $ac_cv_type_long_long_int = yes; then
    AC_DEFINE([HAVE_LONG_LONG_INT], [1],
      [Define to 1 if the system has the type 'long long int'.])
  fi
])

# Define HAVE_UNSIGNED_LONG_LONG_INT if 'unsigned long long int' works.
# This fixes a bug in Autoconf 2.61, and can be faster
# than what's in Autoconf 2.62 through 2.68.

# Note: If the type 'unsigned long long int' exists but is only 32 bits
# large (as on some very old compilers), AC_TYPE_UNSIGNED_LONG_LONG_INT
# will not be defined. In this case you can treat 'unsigned long long int'
# like 'unsigned long int'.

AC_DEFUN([AC_TYPE_UNSIGNED_LONG_LONG_INT],
[
  AC_CACHE_CHECK([for unsigned long long int],
    [ac_cv_type_unsigned_long_long_int],
    [ac_cv_type_unsigned_long_long_int=yes
     if test "x${ac_cv_prog_cc_c99-no}" = xno; then
       AC_LINK_IFELSE(
         [_AC_TYPE_LONG_LONG_SNIPPET],
         [],
         [ac_cv_type_unsigned_long_long_int=no])
     fi])
  if test $ac_cv_type_unsigned_long_long_int = yes; then
    AC_DEFINE([HAVE_UNSIGNED_LONG_LONG_INT], [1],
      [Define to 1 if the system has the type 'unsigned long long int'.])
  fi
])

# Expands to a C program that can be used to test for simultaneous support
# of 'long long' and 'unsigned long long'. We don't want to say that
# 'long long' is available if 'unsigned long long' is not, or vice versa,
# because too many programs rely on the symmetry between signed and unsigned
# integer types (excluding 'bool').
AC_DEFUN([_AC_TYPE_LONG_LONG_SNIPPET],
[
  AC_LANG_PROGRAM(
    [[/* For now, do not test the preprocessor; as of 2007 there are too many
         implementations with broken preprocessors.  Perhaps this can
         be revisited in 2012.  In the meantime, code should not expect
         #if to work with literals wider than 32 bits.  */
      /* Test literals.  */
      long long int ll = 9223372036854775807ll;
      long long int nll = -9223372036854775807LL;
      unsigned long long int ull = 18446744073709551615ULL;
      /* Test constant expressions.   */
      typedef int a[((-9223372036854775807LL < 0 && 0 < 9223372036854775807ll)
                     ? 1 : -1)];
      typedef int b[(18446744073709551615ULL <= (unsigned long long int) -1
                     ? 1 : -1)];
      int i = 63;]],
    [[/* Test availability of runtime routines for shift and division.  */
      long long int llmax = 9223372036854775807ll;
      unsigned long long int ullmax = 18446744073709551615ull;
      return ((ll << 63) | (ll >> 63) | (ll < i) | (ll > i)
              | (llmax / ll) | (llmax % ll)
              | (ull << 63) | (ull >> 63) | (ull << i) | (ull >> i)
              | (ullmax / ull) | (ullmax % ull));]])
])

Name	Type	Size	Permission	Last Modified	Actions
.	DIR	-	drwxr-xr-x	2025-08-28 10:58:31
..	DIR	-	drwxr-xr-x	2025-10-16 10:59:21
bison-i18n.m4	text/x-m4	1.88 KB	-rw-r--r--	2019-10-12 12:28:39
codeset.m4	text/x-m4	842 B	-rw-r--r--	2016-03-20 07:37:53
extern-inline.m4	text/x-m4	4.27 KB	-rw-r--r--	2016-05-28 12:29:03
fcntl-o.m4	text/x-m4	4.56 KB	-rw-r--r--	2016-03-20 07:37:53
fontutil.m4	text/x-m4	13.83 KB	-rw-r--r--	2021-10-09 11:41:50
freetype2.m4	text/x-c	6.18 KB	-rw-r--r--	2018-04-22 09:41:36
gettext.m4	text/x-c	15.49 KB	-rw-r--r--	2016-05-28 12:29:03
glibc2.m4	text/x-c	830 B	-rw-r--r--	2016-03-20 07:37:53
glibc21.m4	text/x-c	907 B	-rw-r--r--	2016-03-20 07:37:53
gpg-error.m4	text/x-m4	4.65 KB	-rw-r--r--	2019-10-12 12:20:46
gpgrt.m4	text/x-m4	4.61 KB	-rw-r--r--	2019-10-12 12:20:46
iconv.m4	text/x-c	9.06 KB	-rw-r--r--	2016-03-20 07:37:53
intdiv0.m4	text/x-c	2.35 KB	-rw-r--r--	2016-05-28 12:29:03
intl.m4	text/x-m4	11.84 KB	-rw-r--r--	2016-03-20 07:37:53
intldir.m4	text/x-m4	917 B	-rw-r--r--	2016-03-20 07:37:53
intlmacosx.m4	text/x-m4	2.47 KB	-rw-r--r--	2016-03-20 07:37:53
intmax.m4	text/x-c	1.1 KB	-rw-r--r--	2016-03-20 07:37:53
inttypes-pri.m4	text/x-c	1.22 KB	-rw-r--r--	2016-03-20 07:37:53
inttypes_h.m4	text/x-c	1020 B	-rw-r--r--	2016-03-20 07:37:53
lcmessage.m4	text/x-m4	1.33 KB	-rw-r--r--	2016-03-20 07:37:53
lib-ld.m4	text/x-m4	3.6 KB	-rw-r--r--	2016-06-11 12:59:32
lib-link.m4	text/x-m4	32.28 KB	-rw-r--r--	2016-06-11 12:59:32
lib-prefix.m4	text/x-m4	8.27 KB	-rw-r--r--	2016-06-11 12:59:32
libgcrypt.m4	text/x-m4	6.09 KB	-rw-r--r--	2022-06-28 11:54:07
libtool.m4	text/x-m4	298.69 KB	-rw-r--r--	2019-10-11 02:55:28
libxml.m4	text/x-c	7.7 KB	-rw-r--r--	2017-07-23 05:10:06
libxslt.m4	text/x-c	7.93 KB	-rw-r--r--	2009-05-12 06:29:34
lock.m4	text/x-m4	1.43 KB	-rw-r--r--	2016-03-20 07:37:53
longlong.m4	text/x-m4	4.63 KB	-rw-r--r--	2016-03-20 07:37:53
ltargz.m4	text/x-m4	2.51 KB	-rw-r--r--	2019-10-11 02:55:28
ltdl.m4	text/x-Algol68	29.33 KB	-rw-r--r--	2019-10-11 02:55:28
ltoptions.m4	text/x-m4	14.17 KB	-rw-r--r--	2019-10-11 02:55:28
ltsugar.m4	text/plain	4.28 KB	-rw-r--r--	2019-10-11 02:55:28
ltversion.m4	text/plain	699 B	-rw-r--r--	2019-10-11 02:55:28
lt~obsolete.m4	text/plain	6 KB	-rw-r--r--	2019-10-11 02:55:28
mysql.m4	text/x-m4	4.12 KB	-rw-r--r--	2025-07-28 03:52:28
nls.m4	text/x-m4	1.19 KB	-rw-r--r--	2016-03-20 07:37:53
pkg.m4	text/x-m4	12.37 KB	-rw-r--r--	2017-03-24 05:16:18
po.m4	text/x-m4	18.52 KB	-rw-r--r--	2016-03-20 07:37:53
printf-posix.m4	text/x-c	1.54 KB	-rw-r--r--	2016-03-20 07:37:53
progtest.m4	text/x-m4	3.02 KB	-rw-r--r--	2016-03-20 07:37:53
size_max.m4	text/x-c	2.99 KB	-rw-r--r--	2016-03-20 07:37:53
stdint_h.m4	text/x-m4	995 B	-rw-r--r--	2016-03-20 07:37:53
threadlib.m4	text/x-c	14.8 KB	-rw-r--r--	2016-03-20 07:37:53
uintmax_t.m4	text/x-m4	1.09 KB	-rw-r--r--	2016-03-20 07:37:53
visibility.m4	text/x-m4	3.27 KB	-rw-r--r--	2016-03-20 07:37:53
wchar_t.m4	text/x-m4	818 B	-rw-r--r--	2016-03-20 07:37:53
wint_t.m4	text/x-c	1.03 KB	-rw-r--r--	2016-03-20 07:37:53
xsize.m4	text/x-m4	406 B	-rw-r--r--	2016-03-20 07:37:53

~ ACUPOFTEA - mail.ontime-ae.com